þþþþþ
 ÝÛÛÛÞ
 ÝÛÛÛÞ  ENHANCING DOS EDITOR (EDIT.COM)
 þþþþþ


 Name: ED.BAT
 -----
 Type: DOS batch file
 -----
 Description: 
 ------------
  This utility uses /G flag of QBASIC.EXE with /EDITOR flag to have
  faster updates on a CGA Monitor.

  If you have a CGA Monitor then just key in the given Batch Script 
  and save it as ED.BAT. Use this file instead of EDIT.COM with the 
  following syntax -

       ED [[drive:][path]filename]
  
  EDIT.COM comes bundled with DOS and acts as the front-end for 
  invoking QBASIC.EXE in the MS-DOS Editor mode. Normally it resides 
  in the \DOS directory. ED.BAT also acts as a similiar front-end. 
  And for all practical purposes you can even delete EDIT.COM and 
  rename ED.BAT as EDIT.BAT and use it in place of EDIT.COM.

 Batch Script:
 -------------
        @echo off
        rem Run MS-DOS editor with FAST screen update
        rem on a CGA monitor 
        qbasic /g /editor %1

ÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜ


 þþþþþ
 ÝÛÛÛÞ
 ÝÛÛÛÞ  ENVIRONMENT VARIABLES
 þþþþþ


 Name: SEL.BAT
 -----
 Type: DOS batch file
 -----
 Purpose: 
 --------
  To effectively manage environment variables for various application.

 Description: 
 ------------
  Environment Varaiables(EVs) are used to control batch files and 
  programs behaviour. These are also used to control the way
  DOS appears and works. Some of the standard EVs are :
  PATH, PROMPT, SHELL etc. The variables can be user defined or
  set by any application when run. Some specific EVs may need to
  be set before some application can run.

  As more and more DOS applications are loaded in a system, the 
  list of EVs like PATH,etc. keep on increasing.This consumes 
  more memory and moreover in certain cases exceeds the default 
  environment size (256 bytes) reserved for EVs.
  Besides this the environment also gets cluttered with long PATH
  description and variables which make it difficult to read. 
  
  When an EV is set for some job, it has to be explicitly removed
  when the job is over and there is no more need for the EV.
  Secondly a copy of the current environment is always passed to
  the next program which is run whether the program requires it or
  not.  If the program is memory resident(TSR) then the duplicate 
  environment copy also stays in the memory thus tying up RAM space
  needlessly.

  The batch file SEL.BAT provides an easy way to manage the EVs.
  Before running any application the EVs can be set as per 
  requirement and when the work is over they can be cleared out.

  Basically SEL.BAT is a simple menu driven program which accepts
  the user's choice and sets the EVs specific to any application
  selected by the user. The user input is accepted by CHOICE.COM,
  a program bundled with DOS 6.0 onwards, and returns an ERRORLEVEL
  number based on which key the user had pressed. Instead of CHOICE 
  the program ASK, from Norton Utilities, can also be used.

  SEL.BAT can be modified to suit individual systems. The modification
  has to be carried out in three parts (as labelled in the SEL.BAT 
  file).

  Part 1 - MENU :
  Here add the menu heading you want to display for your application.
  And add the selected trigger key to the CHOICE command line.
  Ensure each trigger key is unique for each menu option.

  Part 2 - IF CONDITIIONALS :
  Add an IF line with proper ERRORLEVEL number and a goto label.

  Part 3 - EV SETUP MODULES: 
  Add in all the EVs to be set up for the application and any other
  actions to be taken.

  You should also add any EVs which need to be cleared/modified after
  the application is over to the RESET module.

Batch Script:
-------------
@ECHO OFF
rem =========== Begin Part - 1  MENU ===========================

echo      SET ENVIRONMENT
echo      ===============
echo W: Windows         C: Clipper         F: Foxpro
echo T: Turbo C++       X: Xbase           G: Games
echo D: Turbo Debug     E: Display Env.    R: Reset Env.
echo.

rem Add the trigger letter of any newly added menu option in the
rem choice command below :
choice /c:WCERFTXGD  /n "Select : "

rem =========== End Part - 1    MENU ===========================


rem =========== Begin Part - 2  IF CONDITIONALS =================

if errorlevel == 9 goto TDEBUG
if errorlevel == 8 goto GAMES
if errorlevel == 7 goto XBASE
if errorlevel == 6 goto TURBOC
if errorlevel == 5 goto FOX
if errorlevel == 4 goto RESET
if errorlevel == 3 goto END
if errorlevel == 2 goto CLIP
if errorlevel == 1 goto WIN

rem ============ End Part - 2   IF CONDITIONALS ================= 


rem ============ Begin Part - 3  EV SETUP MODULES ===============

rem SETUP MODULE FORMAT
rem :

rem EV1
rem EV2
rem .
rem .
rem EVn
rem 

rem goto END

rem Turbo Debug module
:TDEBUG
PATH=%path%;D:\TD 
goto END

rem Games setup module
:GAMES
d:\gam\gam
goto END

rem Xbase setup module
:XBASE
PATH=%path%;D:\XBASE
append d:\xbase /x:on
goto END

rem Turbo C++ setup module
:TURBOC
rem mode co80
PATH=%path%;D:\TC\BIN
goto END

rem Foxpro setup module
:FOX
PATH=%path%;D:\FOX
goto END

rem Windows setup module
:WIN
PATH=%path%;D:\WINDOWS
goto END

rem Clipper setup module
:CLIP
PATH=%path%;d:\CLIP\BIN
SET CLIPPER=F40
SET INCLUDE=d:\CLIP\INCLUDE
SET LIB=d:\CLIP\LIB
SET OBJ=d:\CLIP\OBJ
SET PLL=d:\CLIP\PLL
goto END

rem ============ End Part - 3  EV SETUP MODULES =================

rem Reset Env. module
:RESET
rem *** Reset the environment variables 
rem *** to default/startup values
mode mono
PATH=C:\DOS;D:\DOS;C:\TOOLS
SET CLIPPER=
SET INCLUDE=
SET LIB=
SET OBJ=
SET PLL=
append ;
goto END

:END
rem Display Current Env.
set

ÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜ


 þþþþþ
 ÝÛÛÛÞ
 ÝÛÛÛÞ  A SIMPLE REMINDER
 þþþþþ


 Name: TODO.BAT
 -----
 Type: DOS batch file
 -----
 Purpose: 
 --------
  To keep track of jobs which you have to do and keep forgetting. To keep
  track of various versions of the project/data on your hard drive.

 Description: 
 ------------


 Batch Script:
 -------------
@echo off

rem SIMPLE TO DO LIST
rem (c) Atanu, 4/04/97, New Delhi
rem FILES:
rem    resp  -- response filr; ENTER
rem    date.tmp -- temp file
rem    to_do.txt -- the file storing the schedule details
rem    todo.bat -- the actual batch file
rem

rem INSTALLATION:
rem * Put all the files in a seperate directory. Name it anything e.g. TODO.
rem   Set the location "t_path" variable below accordingly 
rem * Set the "editor" variable, below, to your favourite editor
rem * Put the TODO.BAT file in the DOS directory or any other directory which
rem   is in the system path
rem * OPTIONAL: Add a line TODO.BAT in your autoxec.bat so that it gets 
rem     executed evertime the computer starts.

rem HOW TO USE:
rem * Type TODO [ENTER] whenever you want to see or edit your scheduled list of
rem   tasks.
rem * While in the editor delete any extra date line
 
rem set todo location
set t_path=c:\todo\

rem set the editor name & path
set t_editor=c:\dos\vi

if "%1"=="-d" goto date
goto edit

:date
date < %t_path%resp > %t_path%date.tmp
echo ***************************** >> %t_path%date.tmp
type %t_path%to_do.txt >> %t_path%date.tmp
copy %t_path%date.tmp %t_path%to_do.txt > nul

:edit
%t_editor% %t_path%to_do.txt

:cleanup
set t_path=
set t_editor=

ÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜ